Toggle Static Property of a Flash sprite

Added on 7/6/2000

Compatibilities:
behavior Mac Shockwave

This item has not yet been rated

Author: KumarK

Toggle Static Property of a Flash sprite

Download PC Source    Download Mac Source

----written for Director 8----
----Kumar.K----
----kumark@icode.com----

----Custom Properties----
property WhichSprite,WhereTo

----Get Behavior description----
on getBehaviorDescription
  return "This Behavior Toggles the Static Property of a Flash Sprite" & RETURN & RETURN &
  "Parameters" & RETURN &
  "* Flash Sprite." & RETURN &
  "* Where to attach this Script"
end
----Get Behavior description----

----Get Behavior Parameters----
on getPropertyDescriptionList
  set description = [:]
  theflashmemlist = searchflashsprite()
  if theflashmemlist.count > 0  then
    addProp description, #WhichSprite, [#format:#Integer, #comment: "Which Flash Sprite ?",#range:theflashmemlist,#default:theflashmemlist[1]]
  else
    addProp description, #WhichSprite, [#format:#Integer, #comment: "Which Flash Sprite ?",#default:1]
  end if
  if the currentspritenum = 0 then
    addProp description, #WhereTo, [#comment: "Where To Attach ?" ,#format:#String,
    #range:["On EnterFrame","On ExitFrame"],#default:"On EnterFrame"]
  else
    addProp description, #WhereTo, [#comment: "Where To Attach ?" ,#format:#String,
    #range:["On MouseUp","On MouseDown","On MouseEnter","On MouseLeave"],#default:"On MouseUp"]
  end if
  return description
end
----Get Behavior Parameters----

----Can be attached to both Sprite and Frame Scripts----
on isOKToAttach (me, aSpriteType, aSpriteNum)
  case aSpriteType of
    #graphic:
      return True
    #script:
      return True
  end case
end isOKToAttach
----Can be attached to both Sprite and Frame Scripts----

----Search for Flash Member on the Stage----
on searchflashsprite
  set theflashmemlist = []
  repeat with i=1 to the lastchannel
    if sprite(i).member.type = #flash then
      theflashmemlist.append(i)
    end if
  end repeat
  return theflashmemlist
end
----Search for Flash Member on the Stage----

----Events----
on EnterFrame me
  if WhereTo = "On EnterFrame" then
    setStaticProp
  end if
end EnterFrame

on ExitFrame me
  if WhereTo = "On ExitFrame" then
    setStaticProp
  end if
end ExitFrame

on MouseUp
  if WhereTo = "On MouseUp" then
    setStaticProp
  end if
end MouseUp

on MouseDown
  if WhereTo = "On MouseDown" then
    setStaticProp
  end if
end MouseDown

on MouseEnter
  if WhereTo = "On MouseEnter" then
    setStaticProp
  end if
end MouseEnter

on MouseLeave
  if WhereTo = "On MouseLeave" then
    setStaticProp
  end if
end MouseLeave
----Events----

----Custom Handler to set Static Property----
on setStaticProp
  if member (sprite(WhichSprite).member).type = #Flash then
    sprite(WhichSprite).Static = not (sprite(WhichSprite).Static)
  end if
end
----Custom Handler to set Static Property----

Upload Provided by ABCUpload ASP

Contact

MMI
22 West Court Sq
Suite 2C
Newnan, GA 30263
USA

Fax - (206) 339-5833

Send e-mail