Increase/ Decrease ViewScale Property of a Flash Member

Added on 7/6/2000

Compatibilities:
behavior Mac Shockwave

This item has not yet been rated

Author: KumarK

Increase/Decrease ViewScale Property of a Flash Member

Download PC Source    Download Mac Source

----written for Director 8----
---- Kumar.K----
----kumark@icode.com----

----Custom Properties ------
property theMember,WhereTo,steps,action
----Get Behavior description----
on getBehaviorDescription
  return "This Behavior Increase/Decrease the ViewScale Property of a Flash Member" & RETURN & RETURN & \
  "Parameters" & RETURN & \
  "* Flash Member." & RETURN & \
  "* Increase/Decrease." & RETURN & \
  "* ViewScale Steps." & RETURN & \
  "* Where to attach this Script"
end
----Get Behavior description----

----Get Behavior Parameters----
on getPropertyDescriptionList
  flashmememberlist = searchflashMember()
  set description = [:]
  if  flashmememberlist.count() > 0 then
    addProp description, #theMember, [#format:#String, #comment: "Which Flash Member ?", \
  #range:flashmememberlist,#default:flashmememberlist[1]]
  else
    addProp description, #theMember, [#format:#Graphic, #comment: "Which Flash Member ?",#default:1]
  end if
  addProp description, #action, [#format:#String, #comment: "Set Action To :", \
  #range:["Increase","Decrease"],#default:"Increase"]
  addProp description, #steps, [#format:#Integer, #comment: "Set ViewScale steps To(Increase/Decrease) :", \
  #range:[#Min: 10, #max: 50],#default:10]
  if the currentspritenum = 0 then
    addProp description, #WhereTo, [#comment: "Where To Attach ?" ,#format:#String, \
    #range:["On EnterFrame","On ExitFrame"],#default:"On EnterFrame"]
  else
    addProp description, #WhereTo, [#comment: "Where To Attach ?" ,#format:#String, \
    #range:["On MouseUp","On MouseDown","On MouseEnter","On MouseLeave"],#default:"On MouseUp"]
  end if
  return description
end
----Get Behavior Parameters----

----Can be attached to both Sprite and Frame Scripts----
on isOKToAttach (me, aSpriteType, aSpriteNum)
  case aSpriteType of
    #graphic:
      return True
    #script:
      return True
  end case
end isOKToAttach
----Can be attached to both Sprite and Frame Scripts----

----Search for Flash Member----
on searchflashMember me
  FlashMembersList = []
  maxCastLib = the number of castLibs
  repeat with theCastLib = 1 to maxCastLib
    maxMember = the number of members of castLib theCastLib
    repeat with memberNumber = 1 to maxMember
      theMember = member(memberNumber, theCastLib)
      if theMember.type = #Flash then
        if theMember.name = EMPTY then
          FlashMembersList.append(theMember)
        else
          FlashMembersList.append(theMember.name)
        end if
      end if
    end repeat
  end repeat
  return FlashMembersList
end
----Search for Flash Member----

----Events----
on EnterFrame me
  if WhereTo = "On EnterFrame" then
    ViewScaleProp
  end if
end EnterFrame

on ExitFrame me
  if WhereTo = "On ExitFrame" then
    ViewScaleProp
  end if
end ExitFrame

on MouseUp
  if WhereTo = "On MouseUp" then
    ViewScaleProp
  end if
end MouseUp

on MouseDown
  if WhereTo = "On MouseDown" then
    ViewScaleProp
  end if
end MouseDown

on MouseEnter
  if WhereTo = "On MouseEnter" then
    ViewScaleProp
  end if
end MouseEnter

on MouseLeave
  if WhereTo = "On MouseLeave" then
    ViewScaleProp
  end if
end MouseLeave
----Events----

----Custom Handler to set ViewScale Property----
on ViewScaleProp
  if member (theMember).type = #Flash then
    member(theMember).scaleMode = #autoSize
    case action of
      "Increase":
        if member(theMember).ViewScale < 1000 then
          member(theMember).ViewScale = member(theMember).ViewScale + steps
        end if

      "Decrease":
        if member(theMember).ViewScale > 50 then
          member(theMember).ViewScale = member(theMember).ViewScale - steps
        end if
    end case
  end if
end
----Custom Handler to set ViewScale Property----

Upload Provided by ABCUpload ASP

Contact

MMI
22 West Court Sq
Suite 2C
Newnan, GA 30263
USA

Fax - (206) 339-5833

Send e-mail